Mixing scripting languages

This pipeline shows how to use different scripting languages in a single Nextflow pipeline. The first process uses an R script to generate random number pairs, and the second process uses a Python script to calculate the average of each coordinate.

nextflow.enable.types = true

// Pipeline parameters
params {
    range: Integer = 100
}

// Entry workflow
workflow {
    pairs = rTask(params.range)
    result = pyTask(pairs)
    result.view()
}

// R process
process rTask {
    input:
    range: Integer

    output:
    stdout()

    script:
    """
    #!/usr/bin/env Rscript
    x <- runif(10, max = ${range})
    y <- runif(10, max = ${range})
    writeLines(paste(x, y, sep = ", "))
    """
}

// Python process
process pyTask {
    input:
    pairs: String

    stage:
    stdin pairs

    output:
    stdout()

    script:
    """
    #!/usr/bin/env python3
    import sys

    x = 0
    y = 0
    lines = 0
    for line in sys.stdin:
        items = line.strip().split(",")
        x += float(items[0])
        y += float(items[1])
        lines += 1

    print("avg: %s - %s" % (x / lines, y / lines))
    """
}